{
  description = "NixOS/Darwin system configuration";

  inputs = {
    nixpkgs.url = "nixpkgs/nixos-23.11";
    agenix.url = "github:ryantm/agenix";
    home-manager = {
      url = "github:nix-community/home-manager/release-23.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    firefox-gnome-theme = {
      url = "github:rafaelmardojai/firefox-gnome-theme";
      flake = false;
    };
    thunderbird-gnome-theme = {
      url = "github:rafaelmardojai/thunderbird-gnome-theme";
      flake = false;
    };
  };

  outputs = inputs @ { self, nixpkgs, agenix, home-manager, ... }:
    let
      inherit (lib) attrValues;
      inherit (lib.my) mapModules mapModulesRec;

      system = "x86_64-linux";

      mkPkgs = pkgs: extraOverlays:
        import pkgs {
          inherit system;
          config.allowUnfree = true;
          overlays = extraOverlays ++ (lib.attrValues self.overlays);
        };
      pkgs = mkPkgs nixpkgs [];

      lib = nixpkgs.lib.extend (self: super: {
        my = import ./lib {
          inherit pkgs inputs;
          lib = self;
        };
      });
    in {
      lib = lib.my;

      nixosConfigurations = {
        atlas = nixpkgs.lib.nixosSystem {
          modules = [
            home-manager.nixosModules.home-manager
            { nixpkgs.overlays = [ (import ./overlays/gnome.nix) ]; }
            (import ./modules)
            ./hosts/atlas
          ];
          specialArgs = { inherit lib inputs; };
        };
        eos = nixpkgs.lib.nixosSystem {
          modules = [
            home-manager.nixosModules.home-manager
            { nixpkgs.overlays = [ (import ./overlays/gnome.nix) ]; }
            (import ./modules)
            ./hosts/eos
          ];
          specialArgs = { inherit lib inputs; };
        };
        helios = nixpkgs.lib.nixosSystem {
          modules = [
            home-manager.nixosModules.home-manager
            { nixpkgs.overlays = [ (import ./overlays/gnome.nix) ]; }
            (import ./modules)
            ./hosts/helios
          ];
          specialArgs = { inherit lib inputs; };
        };
        odyssey = nixpkgs.lib.nixosSystem {
          modules = [
            home-manager.nixosModules.home-manager
            agenix.nixosModules.default
            { nixpkgs.overlays = [ (import ./overlays/gnome.nix) ]; }
            (import ./modules)
            ./hosts/odyssey
          ];
          specialArgs = { inherit lib inputs; };
        };
      };
  };
}